Arkadia MUD RPG

Czy da sie zmienic rodziaj emulatora pod wintin'em? Stantartowo jest cygwin ktory nie obsluguje klawiatury numerycznej tak jak powinien co doprowadza mnie do frustracji. Inaczej znalazlbym czas na przerzucenie sie z mega wolnego zmuda na cos o wiele wiekszej mocy... w tym przypadku tintin

Trooph: Skopiuj plik tt++.exe z katalogu, w którym zainstalowałeś wintina do katalogu /bin cygwina. Później wystarczy uruchomić terminal mintty, jeśli masz taki zainstalowany.

Kod: Zaznacz cały

D:\cygwin\bin\mintty.exe -i /Cygwin-Terminal.ico -

Na cygwinie w terminalu mintty klawiatura numeryczna będzie działać, a np. na rxvt już nie. Odnośnie szybkości działania to faktycznie tintin zostawia daleko w tyle zmuda.

Pytałeś w temacie zmuda o ocenę zbroi. Może Ci się to przyda jeśli zdecydujesz się pozostać na tintinie.

Kod: Zaznacz cały

#nop ocenazbroi.tin
#nop Na podstawie statow zbroi dodaje dodatkowy wiersz z informacja

#nop niezle przed obrazeniami klutymi i obuchowymi oraz dosc dobrze przed cietymi.
#action {jak na %1 chron{i|ia} {on|ona|one} %2 przed obrazeniami %3 i %4 oraz %5 przed %6.}{
#var {jakosc1}{@jakazbroja{%2}};
#var {jakosc2}{@jakazbroja{%5}};
#sh {<dee>%1:<070> %3: $jakosc1, %4: $jakosc1, %6: $jakosc2}
}

#nop dobrze przed obrazeniami klutymi, cietymi i obuchowymi
#action {jak na %1 chron{i|ia} {on|ona|one} %2 przed obrazeniami %3, %4 przed %5 i %6 przed %7.}{
#var {jakosc1}{@jakazbroja{%2}};
#var {jakosc2}{@jakazbroja{%4}};
#var {jakosc3}{@jakazbroja{%6}};
#sh {<dee>%1:<070> %3: $jakosc1, %5: $jakosc2, %7: $jakosc3}
}

#nop jak na ciezka zbroje chroni on dosc dobrze przed obrazeniami klutymi, cietymi i obuchowymi.
#action {jak na %1 chron{i|ia} {on|ona|one} %2 przed obrazeniami klutymi, cietymi i obuchowymi.}{
#var {jakosc}{@jakazbroja{%2}};
#sh {<dee>%1:<070> cietymi: $jakosc, klutymi: $jakosc, obuchowymi: $jakosc}
}

#function {jakazbroja}{
#var {obr}{%1};
#replace {obr}{wyjatkowo zle}{<110>1/12<070>};
#replace {obr}{bardzo zle}{<110>2/12<070>};
#replace {obr}{niezle}{<130>7/12<070>};
#replace {obr}{zle}{<110>3/13<070>};
#replace {obr}{bardzo kiepsko}{<110>4/12<070>};
#replace {obr}{kiepsko}{<130>5/12<070>};
#replace {obr}{przyzwoicie}{<130>6/12<070>};
#replace {obr}{dosc dobrze}{<130>8/12<070>};
#replace {obr}{bardzo dobrze}{<120>10/12<070>};
#replace {obr}{dobrze}{<120>9/12<070>};
#replace {obr}{doskonale}{<120>11/12<070>};
#replace {obr}{perfekcyjnie}{<120>12/12<070>};
#return $obr
}

Co dokładnie doprowadza Cię do frustracji na standardowym terminalu?

Ralandil pisze:Trooph: Skopiuj plik tt++.exe z katalogu, w którym zainstalowałeś wintina do katalogu /bin cygwina. Później wystarczy uruchomić terminal mintty, jeśli masz taki zainstalowany.

Kod: Zaznacz cały

D:\cygwin\bin\mintty.exe -i /Cygwin-Terminal.ico -

Na cygwinie w terminalu mintty klawiatura numeryczna będzie działać, a np. na rxvt już nie. Odnośnie szybkości działania to faktycznie tintin zostawia daleko w tyle zmuda.

Pytałeś w temacie zmuda o ocenę zbroi. Może Ci się to przyda jeśli zdecydujesz się pozostać na tintinie.

Kod: Zaznacz cały

#nop ocenazbroi.tin
#nop Na podstawie statow zbroi dodaje dodatkowy wiersz z informacja

#nop niezle przed obrazeniami klutymi i obuchowymi oraz dosc dobrze przed cietymi.
#action {jak na %1 chron{i|ia} {on|ona|one} %2 przed obrazeniami %3 i %4 oraz %5 przed %6.}{
#var {jakosc1}{@jakazbroja{%2}};
#var {jakosc2}{@jakazbroja{%5}};
#sh {<dee>%1:<070> %3: $jakosc1, %4: $jakosc1, %6: $jakosc2}
}

#nop dobrze przed obrazeniami klutymi, cietymi i obuchowymi
#action {jak na %1 chron{i|ia} {on|ona|one} %2 przed obrazeniami %3, %4 przed %5 i %6 przed %7.}{
#var {jakosc1}{@jakazbroja{%2}};
#var {jakosc2}{@jakazbroja{%4}};
#var {jakosc3}{@jakazbroja{%6}};
#sh {<dee>%1:<070> %3: $jakosc1, %5: $jakosc2, %7: $jakosc3}
}

#nop jak na ciezka zbroje chroni on dosc dobrze przed obrazeniami klutymi, cietymi i obuchowymi.
#action {jak na %1 chron{i|ia} {on|ona|one} %2 przed obrazeniami klutymi, cietymi i obuchowymi.}{
#var {jakosc}{@jakazbroja{%2}};
#sh {<dee>%1:<070> cietymi: $jakosc, klutymi: $jakosc, obuchowymi: $jakosc}
}

#function {jakazbroja}{
#var {obr}{%1};
#replace {obr}{wyjatkowo zle}{<110>1/12<070>};
#replace {obr}{bardzo zle}{<110>2/12<070>};
#replace {obr}{niezle}{<130>7/12<070>};
#replace {obr}{zle}{<110>3/13<070>};
#replace {obr}{bardzo kiepsko}{<110>4/12<070>};
#replace {obr}{kiepsko}{<130>5/12<070>};
#replace {obr}{przyzwoicie}{<130>6/12<070>};
#replace {obr}{dosc dobrze}{<130>8/12<070>};
#replace {obr}{bardzo dobrze}{<120>10/12<070>};
#replace {obr}{dobrze}{<120>9/12<070>};
#replace {obr}{doskonale}{<120>11/12<070>};
#replace {obr}{perfekcyjnie}{<120>12/12<070>};
#return $obr
}

Co dokładnie doprowadza Cię do frustracji na standardowym terminalu?

Dziekuje

JAk narazie wkurzam sie przy nauce obslugi. A przy standardowym frustrowalo mnie wlasnie to ze nie moglem w zaden sposob odpalic rozy wiatrow.. Przez co powracalem do zmuda w ktory mam wszystko juz oskryptowane
Na forum tintin czytalem ze uruchamiajac przez cygwin'a tintin spowalnia troche...
WIem ze troche czasu mi zajmie nauka wszystkiego..ale rowniez wiem ze beda z tego nie male korzysci w postaci sprawnie i szybko dzialajacego clienta.

Widząc wycinek mapy w górnej części ekranu nie widzę sensu stosowania róży wiatrów. Jednak to tylko moja opinia i jeśli ktoś jej potrzebuje to niech używa. Nie miałem okazji porównywać szybkości działania po cygwinem więc trudno jest mi się do tego odnieść. Sam korzystam jedynie z linuksa i w terminalu rxvt, skompilowany ze źródeł tintin działa zabójczo szybko.

PS Chyba nie należy cytować notek jeśli odpowiadamy na nie zaraz pod spodem.

Hm, a czy da sie zrobic tak by mi wykrywal klawe numeryczna z wlaczonym num lockiem?

Gdzie znajde liste klawiszy z ich kodami bym mogl sobie wszystko sam poustawiac?
Przepraszam ze jestem taki upierdliwy ale bez pomocy na pewno nie przejde przez faze poczatkowa

Edit:
Powoli zaczynam do czegos dochodzic. Juz wiem czemu nie mozna miec wlaczonego num locka... takze pozostawie to tak jak jest.

Czy rozdzielanie patternow dziala tak samo jak w zmudzie? |rani|lekko rani|bardzo ciezko rani etc? rozumiem ze wszystkie dluzsze komendy czy patterny maja byc w {}

Klawiatura numeryczna może działać w trzech trybach.
Listę kodów najlepiej sobie sprawdzić samemu. Uruchom "gołego" tintina (pusty plik main.tin, brak wskazania konfiguracji) i popróbuj np.

numpad 4 wyświetli kod:

Kod: Zaznacz cały

\eOt

alt + numpad 4 wyświetli kod:

Kod: Zaznacz cały

\e\eOt

F1 wyświetli kod:

Kod: Zaznacz cały

\e[11~

Rozdzielenie patternów działa podobnie np.

Kod: Zaznacz cały

#high {{ledwo muska|lekko rani|rani} cie}{<110>}

Pytanko jak osiagnac takie czyste subowanie jak Dogid na str 9 tego tematu.
Mi wychodzi taki brzydki badziew korzystajac z subow
wyjscia: Nny-W, S i E.

Wszystko idzie powoli i do przodu. Watpie bym osiagnal poziom zaawansowany w skryptowaniu tintina ale poki co baardzo mi sie podoba

Nie używam czegoś takiego (ograniczyłem skrypty do minimum) więc napisałem tak na szybko:

Kod: Zaznacz cały

#action {{Jest|Sa} tutaj %* wyjs{cia|cie|c}: %2.}{
#var {wyjscia}{%2};
#replace {wyjscia}{\bpolnocny-wschod\b}{NE};
#replace {wyjscia}{\bpoludniowy-wschod\b}{SE};
#replace {wyjscia}{\bpoludniowy-zachod\b}{SW};
#replace {wyjscia}{\bpolnocny-zachod\b}{NW};
#replace {wyjscia}{\bpolnoc\b}{N};
#replace {wyjscia}{\bzachod\b}{W};
#replace {wyjscia}{\bwschod\b}{E};
#replace {wyjscia}{\bpoludnie\b}{S};
#line gag;
#echo {Wyjscia: $wyjscia}
}

Aby zamieniało nam wszędzie kierunki należy uwzględnić pozostałe przypadki (np. W mroku nocy dostrzegasz..., Trakt rozgalezia sie na...) i można sobie jeszcze wydzielić zamianę do osobnej funkcji w następujący sposób:

Kod: Zaznacz cały

#action {{Jest|Sa} tutaj %* wyjs{cia|cie|c}: %2.}{
#var {wyjscia}{@zamwyjscia{%2}};
#line gag;
#echo {Wyjscia: $wyjscia}
}

#function {zamwyjscia}{
#var {wyjscia}{%1};
#replace {wyjscia}{\bpolnocny-wschod\b}{NE};
#replace {wyjscia}{\bpoludniowy-wschod\b}{SE};
#replace {wyjscia}{\bpoludniowy-zachod\b}{SW};
#replace {wyjscia}{\bpolnocny-zachod\b}{NW};
#replace {wyjscia}{\bpolnoc\b}{N};
#replace {wyjscia}{\bzachod\b}{W};
#replace {wyjscia}{\bwschod\b}{E};
#replace {wyjscia}{\bpoludnie\b}{S};
#return $wyjscia
}

co oznacza "\b" w tym przypadku? czy to sprawia ze zamienia tylko dana linie tekstu na to co jest w drugim nawiasie?

1) To tzw. word boundaries. Dodałem z przyzwyczajenia, nie są konieczne w tym przypadku. Warto stosować przy podobnych wyrażeniach np.

Kod: Zaznacz cały

#sub {\bwielki\b \bbialy\b \bkwiat\b}{%0 (nazwa1);
#sub {\bniewielki\b \bbialy\b \bkwiat\b}{%0 (nazwa2);

2) Tak, zamienia na to co masz w drugim nawiasie według składni:
#replace {variable} {oldtext} {newtext}

Edycja: Istotna jest kolejność poleceń #replace, żeby nie było takich kwiatków jak

Kod: Zaznacz cały

poludniowy-W, Nny-E.

Arkadia MUD RPG

TinTin++, skrypty do arkadii v.1.0

Re: TinTin++, skrypty do arkadii v.1.0

Re: TinTin++, skrypty do arkadii v.1.0

Re: TinTin++, skrypty do arkadii v.1.0

Re: TinTin++, skrypty do arkadii v.1.0

Re: TinTin++, skrypty do arkadii v.1.0

Re: TinTin++, skrypty do arkadii v.1.0

Re: TinTin++, skrypty do arkadii v.1.0

Re: TinTin++, skrypty do arkadii v.1.0

Re: TinTin++, skrypty do arkadii v.1.0

Re: TinTin++, skrypty do arkadii v.1.0