Zmud pomoc

Forum techniczne Arkadii.
ODPOWIEDZ
Volomir
Posty: 6
Rejestracja: 11 sie 2014 21:46

Re: Zmud pomoc

Post autor: Volomir »

Nie znam się na skryptowaniu ani nic z tych rzeczy ale chciałbym mieć takie wskaźniki jak są w tym kliencie ze strony.
By pokazywało mi kondycje zmęczenie. Np nawodnienie i głód tez.
Ma ktoś takie coś? Lub było w temacie? Jeśli tak to napiszcie to przebrne przez te 50 stron.
Na górę
Awatar użytkownika
Herenvarno
Posty: 809
Rejestracja: 09 mar 2010 11:22

Re: Zmud pomoc

Post autor: Herenvarno »

Prosze bardzo:

Kod: Zaznacz cały

#CLASS {Config}
#TRIGGER {z hosta} {
  #GAUGE po (POSTEPY) (@VPostepy) (16) (16) "Config|Gauge" "orange" "orange"
  hpOgraniczDoRzeczywistej
  ASytosc
  }
#ALIAS look {zerknij}
#VAR VStan {0}
#CLASS 0
#CLASS {Config|Statystyki}
#ALIAS VPostepy {0}
#ALIAS VSytosc {0}
#VAR VAlkRU {0}
#VAR VAlkRD {0}
#VAR VpijD {20}
#VAR pijany {0}
#VAR prr {0}
#VAR VStan {1}
#VAR VCiezar {1}
#VAR VTrzezwosc {0}
#VAR VStanZdrowia {7}
#VAR VPragnienie {0}
#VAR VZmeczenie {0}
#VAR VSytosc {2}
#VAR WordZdrowie {W Swietnej}
#VAR hpRU {7000}
#VAR hpRD {6000}
#VAR hpU {7000}
#VAR SredniaHP {7000}
#VAR hpD {7000}
#VAR hpLostU {0}
#VAR hpLostD {204}
#VAR VPostepy {4}
#VAR VMana {9}
#VAR PostepyText {NIEBOTYCZNE}
#CLASS 0
#CLASS {Config|Meskie}
#CLASS 0
#CLASS {Config|Meskie|Stausy}
#TRIGGER {^Jestes (*).} {
  #Var VStan {mentalnie w pelni sil|mentalnie lekko oslabiony|mentalnie oslabiony|mentalnie zmeczony|mentalnie bardzo zmeczony|mentalnie w zlej kondycji|mentalnie wyczerpany|mentalnie wykonczony|mentalnie u kresu sil}
  #Var VStan {%ismember( %1, @VStan)}
  #if (@VStan>0) {
    #nomap
    #Math VMana {10-@VStan}
    AMana
    } {
    #Var VStan {bardzo najedzony|najedzony|glodny|bardzo glodny}
    #Var VStan {%ismember( %1, @VStan)}
    #if (@VStan>0) {
      #math VSytosc {@VStan-1}
      ASytosc
      #nomap
      } {
      #Var VStan {trzezwy|podchmielony|lekko podpity|podpity|wstawiony|mocno wstawiony|pijany|schlany|napruty|nawalony|pijany jak bela}
      #Var VStan {%ismember( %1, @VStan)}
      #if (@VStan>0) {
        #Math VTrzezwosc {@VStan-1}
        Alkoholizm @VTrzezwosc
        #nomap
        } {
        #Var VStan {bardzo najedzony|najedzony|glodny|bardzo glodny}
        #Var VStan {%ismember( %1, @VStan)}
        #if (@VStan>0) {
          #Math VSytosc {@VStan-1}
          #nomap
          } {
          #Var VStan {tak zmeczony, ze nie mozesz dalej podazac w tym kierunku}
          #Var VStan {%ismember( %1, @VStan)}
          #if (@VStan>1) {
            #var VZmeczenie {10}
            #nodir
            }
          #if (@VStan=0) {
            #Var VStan {w pelni wypoczety|wypoczety|troche zmeczony|zmeczony|bardzo zmeczony|nieco wyczerpany|wyczerpany|bardzo wyczerpany|wycienczony|calkowicie wycienczony}
            #Var VStan {%ismember( %1, @VStan)}
            }
          #if (@VStan>0) {
            #VAR VZmeczenie {@VStan}
            #Math VZmeczenie {@Vzmeczenie-1}
            #nomap
            } {
            #Var VStan {ledwo zywy|ciezko ranny|w zlej kondycji|ranny|lekko ranny|w dobrym stanie|w swietnej kondycji}
            #Var VStan {%ismember( %1, @VStan)}
            #if (@VStan>0) {
              #if (@VStan=1) {
                #Var WordZdrowie {Ledwo Zywy}
                #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
                }
              #if (@VStan=2) {
                #Var WordZdrowie {Ciezko Ranny}
                #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
                }
              #if (@VStan=3) {
                #Var WordZdrowie {W Zlej}
                #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
                }
              #if (@VStan=4) {
                #Var WordZdrowie {Ranny}
                #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
                }
              #if (@VStan=5) {
                #Var WordZdrowie {Lekko Ranny}
                #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
                }
              #if (@VStan=6) {
                #Var WordZdrowie {W Dobrej}
                #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
                }
              #if (@VStan=7) {#Var WordZdrowie {W Swietnej}}
              #Var VStanZdrowia {@VStan}
              #Math hpRU {1000*@VStanZdrowia}
              #math hpRD {@hpRU-1000}
              hpOgraniczDoRzeczywistej
              #nomap
              #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
              }
            }
          }
        }
      }
    }
  }
#REGEX {^> Jestes (.*)\.} {
  #Var VStan {mentalnie w pelni sil|mentalnie lekko oslabiony|mentalnie oslabiony|mentalnie zmeczony|mentalnie bardzo zmeczony|mentalnie w zlej kondycji|mentalnie wyczerpany|mentalnie wykonczony|mentalnie u kresu sil}
  #Var VStan {%ismember( %1, @VStan)}
  #if (@VStan>0) {
    #Math VMana {10-@VStan}
    AMana
    } {
    #Var VStan {bardzo najedzony|najedzony|glodny|bardzo glodny}
    #Var VStan {%ismember( %1, @VStan)}
    #if (@VStan>0) {
      #math VSytosc {@VStan-1}
      ASytosc
      #nomap
      } {
      #Var VStan {trzezwy|podchmielony|lekko podpity|podpity|wstawiony|mocno wstawiony|pijany|schlany|napruty|nawalony|pijany jak bela}
      #Var VStan {%ismember( %1, @VStan)}
      #if (@VStan>0) {
        #Math VTrzezwosc {@VStan-1}
        Alkoholizm @VTrzezwosc
        #nomap
        } {
        #Var VStan {bardzo najedzony|najedzony|glodny|bardzo glodny}
        #Var VStan {%ismember( %1, @VStan)}
        #if (@VStan>0) {
          #Math VSytosc {@VStan-1}
          #nomap
          } {
          #Var VStan {tak zmeczony, ze nie mozesz dalej podazac w tym kierunku}
          #Var VStan {%ismember( %1, @VStan)}
          #if (@VStan>1) {
            #var VZmeczenie {10}
            #nodir
            }
          #if (@VStan=0) {
            #Var VStan {w pelni wypoczety|wypoczety|troche zmeczony|zmeczony|bardzo zmeczony|nieco wyczerpany|wyczerpany|bardzo wyczerpany|wycienczony|calkowicie wycienczony}
            #Var VStan {%ismember( %1, @VStan)}
            }
          #if (@VStan>0) {
            #VAR VZmeczenie {@VStan}
            #Math VZmeczenie {@Vzmeczenie-1}
            #nomap
            } {
            #Var VStan {ledwo zywy|ciezko ranny|w zlej kondycji|ranny|lekko ranny|w dobrym stanie|w swietnej kondycji}
            #Var VStan {%ismember( %1, @VStan)}
            #if (@VStan>0) {
              #if (@VStan=1) {
                #Var WordZdrowie {Ledwo Zywy}
                #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
                }
              #if (@VStan=2) {
                #Var WordZdrowie {Ciezko Ranny}
                #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
                }
              #if (@VStan=3) {
                #Var WordZdrowie {W Zlej}
                #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
                }
              #if (@VStan=4) {
                #Var WordZdrowie {Ranny}
                #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
                }
              #if (@VStan=5) {
                #Var WordZdrowie {Lekko Ranny}
                #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
                }
              #if (@VStan=6) {
                #Var WordZdrowie {W Dobrej}
                #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
                }
              #if (@VStan=7) {#Var WordZdrowie {W Swietnej}}
              #Var VStanZdrowia {@VStan}
              #Math hpRU {1000*@VStanZdrowia}
              #math hpRD {@hpRU-1000}
              hpOgraniczDoRzeczywistej
              #nomap
              #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
              }
            }
          }
        }
      }
    }
  }
#CLASS 0
#CLASS {Config|Wspolne}
#CLASS 0
#CLASS {Config|Wspolne|Stausy}
#REGEX {^Czujesz, ze (.*)\.} {
  #Var VStan {nie chce ci sie pic|troche chce ci sie pic|chce ci sie pic|chce ci sie bardzo pic}
  #Var VStan {%ismember( %1, @VStan)}
  #if (@VStan>0) {
    #math VPragnienie {@VStan-1}
    #nomap
    APragnienie
    }
  }
#REGEX {^Poczynil(?:es|as) (.*) postepy, od momentu} {
  #Var PostepyText {%1}
  #Var PostepyText {%upper( @PostepyText)}
  #var VStan {minimalne|nieznaczne|bardzo male|male|nieduze|zadowalajace|spore|dosc duze|znaczne|duze|bardzo duze|ogromne|imponujace|wspaniale|gigantyczne|niebotyczne}
  #Var VPostepy {%ismember( %1, @VStan)}
  #GAUGE po (POSTEPY ZADNE) (@VPostepy) (16) (15) "Config|Gauge" "orange" "orange"
  #if (@VPostepy>0) {#GAUGE po (@PostepyText) (@VPostepy) (16) (15) "Config|Gauge" "black" "black"}
  #if (@VPostepy>2) {#GAUGE po (@PostepyText) (@VPostepy) (16) (15) "Config|Gauge" "blue" "blue"}
  #if (@VPostepy>4) {#GAUGE po (@PostepyText) (@VPostepy) (16) (15) "Config|Gauge" "magenta" "magenta"}
  #if (@VPostepy>6) {#GAUGE po (@PostepyText) (@VPostepy) (16) (15) "Config|Gauge" "cyan" "cyan"}
  #if (@VPostepy>8) {#GAUGE po (@PostepyText) (@VPostepy) (16) (15) "Config|Gauge" "orange" "yellow"}
  #if (@VPostepy>10) {#GAUGE po (@PostepyText) (@VPostepy) (16) (15) "Config|Gauge" "purple" "blue"}
  #if (@VPostepy>12) {#GAUGE po (@PostepyText) (@VPostepy) (16) (15) "Config|Gauge" "yellow" "magenta"}
  #if (@VPostepy>14) {#GAUGE po (@PostepyText) (@VPostepy) (16) (15) "Config|Gauge" "green" "green"}
  }
#REGEX {^Wypil(?:es|as) juz tak duzo, ze nie jestes w stanie wmusic w siebie wiecej\.} {
  #Var VPragnienie {0}
  #nomap
  APragnienie
  }
#TRIGGER {^Gasisz pragnienie} {
  #Var VPragnienie {0}
  #nomap
  APragnienie
  }
#TRIGGER {^> Gasisz pragnienie} {
  #Var VPragnienie {0}
  #nomap
  APragnienie
  }
#REGEX {^> Czujesz, ze (.*)\.} {
  #Var VStan {nie chce ci sie pic|troche chce ci sie pic|chce ci sie pic|chce ci sie bardzo pic}
  #Var VStan {%ismember( %1, @VStan)}
  #if (@VStan>0) {
    #math VPragnienie {@VStan-1}
    #nomap
    APragnienie
    }
  }
#REGEX {^> Wypil(?:es|as) juz tak duzo, ze nie jestes w stanie wmusic w siebie wiecej\.} {
  #Var VPragnienie {0}
  #nomap
  APragnienie
  }
#CLASS 0
#CLASS {Config|Gauge}
#BUTTON 1 {W Swietnej} {} {} {} {@SredniaHP} {} {} {} {} {} {} {} {} {32} {} {Gauge||2|6900|7000|15} {} "" {Explore|Inset} {} {zd}
#BUTTON 2 {Zmeczenie} {} {} {} {@VZmeczenie} {} {} {} {} {} {} {} {} {64} {} {Gauge||3|9|3|7} {} "" {Explore|Inset} {} {zm}
#BUTTON 3 {Przeciazenie} {} {} {} {@VCiezar} {} {} {} {} {} {} {} {} {64} {} {Gauge||2|6|3|7} {} "" {Explore|Inset} {} {Ci}
#BUTTON 4 {Pragnienie} {} {} {} {@VPragnienie} {} {} {} {} {} {} {} {} {64} {} {Gauge||4|3|3|7} {} "" {Explore|Inset} {} {pr}
#BUTTON 5 {Glod} {} {} {} {@VSytosc} {} {} {} {} {} {} {} {} {48} {} {Gauge||3|3|3|7} {} "" {Explore|Inset} {} {sy}
#BUTTON 6 {Mana} {} {} {} {@VMana} {} {} {} {} {} {} {} {} {48} {} {Gauge||3|9|8|7} {} "" {Explore|Inset} {} {ma}
#BUTTON 7 {NIEBOTYCZE} {} {} {} {@VPostepy} {} {} {} {} {} {} {} {} {16} {} {Gauge||1|16|15|7} {} "" {Explore|Inset} {} {po}
#CLASS 0
#CLASS {Config|Gauge|KontrolerGauge}
#VAR PostepyText {NIEBOTYCZNE}
#VAR VPostepy {16}
#CLASS 0
#CLASS {Config|Gauge|KontrolerGauge|HP}
#ALIAS hpOgraniczDoRzeczywistej {
  #if (@hpD>@hpRU) {
    #var hpD {@hpRD}
    #var hpU {@hpRU}
    }
  #if (@hpU<@hpRD) {
    #var hpD {@hpRD}
    #var hpU {@hpRU}
    }
  #if (@hpD<@hpRD) {#var hpD {@hpRD}}
  #if (@hpU>@hpRU) {#var hpU {@hpRU}}
  #if (@VStanZdrowia<4) {#GAUGE zd (@WordZdrowie) (@SredniaHP) (6900) (7000) "Config|Gauge" "red" "red" "white"}
  #if (@VStanZdrowia>3 & @VStanZdrowia<6) {#GAUGE zd (@WordZdrowie) (@SredniaHP) (6900) (7000) "Config|Gauge" "yellow" "yellow" "white"}
  #if (@VStanZdrowia>=6) {#GAUGE zd (@WordZdrowie) (@SredniaHP) (6900) (7000) "Config|Gauge" "green" "green" "white"}
  #MATH SredniaHP {(@hpU+@hpD)/2}
  }
#ALIAS hpOgranicz {
  #if (@hpD<0) {#var hpD {0}}
  #if (@hpD>7000) {#var hpD {7000}}
  #math tmp {@VStanZdrowia*1000-1000}
  #if (@hpD<@tmp) {#var hpD {@tmp}}
  #if (@hpU<0) {#var hpU {0}}
  #if (@hpU>@7000) {#var hpU {7000}}
  #math tmp {@VStanZdrowia*1000}
  #if (@hpU>@tmp) {#var hpU {@tmp}}
  #if (@hpU<@hpD) {#var hpU {@hpD}}
  #MATH SredniaHP {(@hpU+@hpD)/2}
  }
#ALIAS ranD {
  #math hpLostD {@hpD*%1}
  #math hpLostD {@hpLostD/100}
  #math hpD {@hpD-@hpLostD}
  #if (@hpD<@hpRD) {#Var hpD {@hpRD}}
  }
#ALIAS ranU {
  #math hpLostU {@hpU*%1}
  #math hpLostU {@hpLostU/100}
  #math hpU {@hpU-@hpLostU}
  #if (@hpU>@hpRU) {#Var hpU {@hpRU}}
  }
#ALIAS Autoleczenie {
  #math hpD {@hpD+25}
  #math hpU {@hpU+25}
  #MATH SredniaHP {(@hpU+@hpD)/2}
  hpOgranicz
  #IF (@hpD>=7000) {
    #Var hpD {7000}
    #T- {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
    }
  }
#TRIGGER {(*) ledwo muska cie} {
  ranU 0
  ranD 4
  hpOgranicz
  #nomap
  #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
  }
#TRIGGER {ledwo muskajac cie w} {
  ranU 0
  ranD 4
  hpOgranicz
  #nomap
  #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
  }
#TRIGGER {(*) masakruje cie} {
  ranU 80
  ranD 101
  hpOgranicz
  #nomap
  #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
  }
#TRIGGER {masakrujac cie w} {
  ranU 80
  ranD 101
  hpOgranicz
  #nomap
  #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
  }
#TRIGGER {(*) rani cie} {
  #var tmp {%word( %1, %numWords( %1))}
  #if (@tmp="lekko") {
    ranU 5
    ranD 9
    } {
    #if (@tmp="ciezko") {
      ranU 20
      ranD 49
      } {
      #if (@tmp="powaznie") {
        ranU 50
        ranD 79
        } {
        ranU 10
        ranD 19
        }
      }
    }
  hpOgranicz
  #nomap
  #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
  }
#TRIGGER {(*) raniac cie w} {
  #var tmp {%word( %1, %numWords( %1))}
  #if (@tmp="lekko") {
    ranU 5
    ranD 9
    } {
    #if (@tmp="ciezko") {
      ranU 20
      ranD 49
      } {
      #if (@tmp="powaznie") {
        ranU 50
        ranD 79
        } {
        ranU 10
        ranD 19
        }
      }
    }
  hpOgranicz
  #nomap
  #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
  }
#TRIGGER {udaje sie uniknac tego ciosu} {#nomap}
#TRIGGER {udaje ci sie jedynie czesciowo zejsc jej z drogi. Skraj zjawy przechodzi (*) sprawiajac ci bol.} {
  ranU 0
  ranD 4
  hpOgranicz
  #nomap
  #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
  }
#TRIGGER {strone, nie udaje ci sie uskoczyc. Mglista sylwetka przenika przez twoje cialo, sprawiajac ci bol.} {
  ranU 5
  ranD 9
  hpOgranicz
  #nomap
  #T+ {Config|Gauge|KontrolerGauge|HP|Esamoleczenie}
  }
#CLASS 0
#CLASS {Config|Gauge|KontrolerGauge|HP|Esamoleczenie} {enable}
#ALARM {4} {Autoleczenie}
#CLASS 0
#CLASS {Config|Gauge|KontrolerGauge|Alkohol}
#ALIAS Alkoholizm {
  #if (@VTrzezwosc=0) {
    #VAR VAlkRU {0}
    #VAR VAlkRD {0}
    } {
    #if (@VTrzezwosc=1) {
      #VAR VAlkRU {10}
      #VAR VAlkRD {0}
      } {
      #if (@VTrzezwosc=2) {
        #VAR VAlkRU {20}
        #VAR VAlkRD {10}
        } {
        #if (@VTrzezwosc=3) {
          #VAR VAlkRU {30}
          #VAR VAlkRD {20}
          } {
          #if (@VTrzezwosc=4) {
            #VAR VAlkRU {40}
            #VAR VAlkRD {30}
            } {
            #if (@VTrzezwosc=50) {
              #VAR VAlkRU {50}
              #VAR VAlkRD {40}
              } {
              #if (@VTrzezwosc=6) {
                #VAR VAlkRU {60}
                #VAR VAlkRD {50}
                } {
                #if (@VTrzezwosc=7) {
                  #VAR VAlkRU {70}
                  #VAR VAlkRD {60}
                  } {
                  #if (@VTrzezwosc=8) {
                    #VAR VAlkRU {80}
                    #VAR VAlkRD {70}
                    } {
                    #if (@VTrzezwosc=9) {
                      #VAR VAlkRU {90}
                      #VAR VAlkRD {80}
                      } {
                      #if (@VTrzezwosc=10) {
                        #VAR VAlkRU {100}
                        #VAR VAlkRD {90}
                        }
                      }
                    }
                  }
                }
              }
            }
          }
        }
      }
    }
  PijNowy
  }
#ALIAS PijNowy {
  #if (@VpijD<@VAlkRD) {#Var VpijD {@VAlkRD}}
  #if (@VpijU>@VAlkRU) {#Var VpijU {@VAlkRU}}
  #Math tmp3 {@VpijU-@VpijD}
  #Math tmp2 {@VpijD-@pijany}
  #Math tmp1 {@tmp3/4}
  #Math tmp4 {@pijany-@VpijU}
  #if (@pijany<@VpijD & @tmp2<@tmp1) {#var pijany {@VpijD}}
  #if (@pijany>@VpijU & @tmp4<@tmp1) {#var pijany {@VpijU}}
  #if (@pijany<@VpijD | @pijany>@VpijU) {#Math pijany {(@VpijD+@VpijU)/2}}
  #T+ {Config|Gauge|KontrolerGauge|Alkohol|Etrzezwiej}
  }
#TRIGGER {^Trunek w (*) jest taki mocny} {
  #VAR VAlkRU {100}
  #VAR VAlkRD {100}
  #T+ {Config|Gauge|KontrolerGauge|Alkohol|Etrzezwiej}
  }
#TRIGGER {^> Trunek w (*) jest taki mocny} {
  #VAR VAlkRU {100}
  #VAR VAlkRD {100}
  #T+ {Config|Gauge|KontrolerGauge|Alkohol|Etrzezwiej}
  }
#CLASS 0
#CLASS {Config|Gauge|KontrolerGauge|Alkohol|Etrzezwiej}
#ALARM {55} {
  #if (@pijany>0) {#math pijany {@pijany-1}}
  #if (@pijany=0) {#T- {Config|Gauge|KontrolerGauge|Alkohol|Etrzezwiej}}
  }
#CLASS 0
#CLASS {Config|Gauge|KontrolerGauge|Przeciazenie}
#TRIGGER {Ciezar twego ekwipunku (*).} {
  #Var VCiezar {wadzi ci troche|daje ci sie we znaki|jest dosyc klopotliwy}
  #Var VCiezar {%ismember( %1, @VCiezar)}
  #GAUGE Ci "Przeciazenie" (@VCiezar) (6) (3) "Config|Gauge" "red" "green"
  }
#TRIGGER {Twoj ekwipunek (*).} {
  #Var VCiezar {jest wyjatkowo ciezki|jest niemilosiernie ciezki|prawie przygniata cie do ziemi|nie wadzi ci ani troche}
  #Var VCiezar {%ismember( %1, @VCiezar)}
  #Math VCiezar {@VCiezar+3}
  #If (@VCiezar=7) {#Var VCiezar {0}}
  #GAUGE Ci "Przeciazenie" (@VCiezar) (6) (3) "Config|Gauge" "red" "green"
  }
#CLASS 0
#CLASS {Config|Gauge|KontrolerGauge|Pragnienie}
#ALIAS APragnienie {
  #GAUGE pr (Pragnienie) (@VPragnienie) (3) (3) "Config|Gauge" "red" "red"
  #if (@VPragnienie=1) {#GAUGE pr (Pragnienie) (@VPragnienie) (3) (3) "Config|Gauge" "green" "green"}
  #if (@VPragnienie=2) {#GAUGE pr (Pragnienie) (@VPragnienie) (3) (3) "Config|Gauge" "yellow" "yellow"}
  #if (@VPragnienie=3) {#GAUGE pr (Pragnienie) (@VPragnienie) (3) (3) "Config|Gauge" "red" "red"}
  }
#CLASS 0
#CLASS {Config|Gauge|KontrolerGauge|Sytosc}
#ALIAS ASytosc {
  #GAUGE sy (Glod) (@VSytosc) (3) (3) "Config|Gauge" "cyan" "cyan"
  #if (@VPragnienie=1) {#GAUGE sy (Glod) (@VSytosc) (3) (3) "Config|Gauge" "green" "green"}
  #if (@VPragnienie=2) {#GAUGE sy (Glod) (@VSytosc) (3) (3) "Config|Gauge" "yellow" "yellow"}
  #if (@VPragnienie=3) {
    #Var TypMuzy {3}
    #GAUGE sy (Glod) (@VSytosc) (3) (3) "Config|Gauge" "red" "red"
    }
  }
#CLASS 0
#CLASS {Config|Gauge|KontrolerGauge|Mana}
#ALIAS AMana {
  #T- {Config|Gauge|KontrolerGauge|Mana|DopelnienieMany}
  #if (@VMana>0 & @VMana<4) {#GAUGE ma (Mana) (@VMana) (9) (2) "Config|Gauge" "red" "red"}
  #if (@VMana>3 & @VMana<6) {#GAUGE ma (Mana) (@VMana) (9) (5) "Config|Gauge" "yellow" "yellow"}
  #if (@VMana>5 & @VMana<8) {#GAUGE ma (Mana) (@VMana) (9) (7) "Config|Gauge" "green" "green"}
  #if (@VMana>7 & @VMana<10) {#GAUGE ma (Mana) (@VMana) (9) (8) "Config|Gauge" "cyan" "cyan"}
  #if (@VMana=9) {#T+ {Config|Gauge|KontrolerGauge|Mana|DopelnienieMany}} {
    #Var VPlusAlarm {0}
    #T- {Config|Gauge|KontrolerGauge|Mana|DopelnienieMany}
    }
  }
#VAR VPlusAlarm {0}
#CLASS 0
#CLASS {Config|Gauge|KontrolerGauge|Mana|DopelnienieMany}
#ALARM {10} {
  #Math VPlusAlarm {@VPlusAlarm+10}
  #if (@VPlusAlarm>599) {
    #Var VPlusAlarm {0}
    #T- {Config|Gauge|KontrolerGauge|Mana|DopelnienieMany}
    }
  }
#CLASS 0

Dziala z konfiguracja "opcji" na arce:

Kod: Zaznacz cały

Interfejs:

SZEROKOSC ekranu:                       0
WYSWIETLANIE zmiany stanu:              Skrocone

Walka:

Wyswietlana KONDYCJA:                   Rozszerzona
Nie każdy jest mile widziany w moim domu. Gdybym wszystkich traktował jednakowo, nikogo nie wyróżniłbym!
Na górę
Thoven
Posty: 18
Rejestracja: 10 paź 2013 18:36

Re: Zmud pomoc

Post autor: Thoven »

Jedna uwaga - to co wkleiłeś działa tylko dla mężczyzn.
Na górę
Volomir
Posty: 6
Rejestracja: 11 sie 2014 21:46

Re: Zmud pomoc

Post autor: Volomir »

Dziękuję bardzo! Właśnie o takim czymś marzyłem.
Na górę
Awatar użytkownika
Herenvarno
Posty: 809
Rejestracja: 09 mar 2010 11:22

Re: Zmud pomoc

Post autor: Herenvarno »

O wersje zenska prosic niestety nalezy moja zone, osobiscie nie mam zenskich postaci, wiec cokolwiek na zmudzie w wersji zenskiej jest, to wszelkie modyfikacje sa prowadzone przez nia wlasnie. Przerobienie tego co powyzej na wersje plci pieknej nie jest trudne (raczej).
Nie każdy jest mile widziany w moim domu. Gdybym wszystkich traktował jednakowo, nikogo nie wyróżniłbym!
Na górę
Fels
Posty: 31
Rejestracja: 17 lip 2014 15:49

Re: Zmud pomoc

Post autor: Fels »

Cześć,
Zdecydowałem się na zMUDa, piszę aliasy, makra i kolorki. Ale pojęcia nie mam jak "podkraść" wasze skrypty. Ktoś mógłby mi wytłumaczyć gdzie wkleić kod skryptu? Korzystam tylko z okienek do wpisywania skryptów i pojęcia nie mam jak wrzucić taki skrypt. Korzystam z wersji 4.62.

Fels.
Na górę
Awatar użytkownika
Herenvarno
Posty: 809
Rejestracja: 09 mar 2010 11:22

Re: Zmud pomoc

Post autor: Herenvarno »

Nie mam pojecia jak w twojej wersji zmuda, nauke skryptowania zaczalem od wersji 7,21
Obsluga poprzednikow jest mi nieznana.

W przypadku powyzszego skryptu:

Kliknij w "Settings" (tuz obok "Chars" )
Otworzy ci sie okno "Settings in Memeory"
Kliknij w taka dosc mala strzaleczke wskazujaca w dol (miedzy "New" i "Delete")
Wybierz opcje "New Class Folder"
Kliknij na nowo utworzonym folderze bez nazwy.
Teraz na samym dole w "Edit Class" kliknij w zakladke "Class script"
Tam mozesz wkleic caly skrypt.
Nie każdy jest mile widziany w moim domu. Gdybym wszystkich traktował jednakowo, nikogo nie wyróżniłbym!
Na górę
Awatar użytkownika
Herenvarno
Posty: 809
Rejestracja: 09 mar 2010 11:22

Re: Zmud pomoc

Post autor: Herenvarno »

Moze ktos potrafi mi poradzic jak to uczynic.
Potrzebuje wyslac czasem "pusta linie" do muda (odpowiednik wklepania enteru -- np. "napisz list;Nazwa_Adresata;Tytul_Listu;Tekst_listu;[enter];Zwyczajowy_podpis;**"),
nie mam jednak pojecia jak to uczynic.
Jakas sugestia?

Sprawa kolejna, mam problemy z polaczeniem sie ze strona Zuggsoftu, czy tylko ja mam z tym problem (wina lezy gdzies po mojej stronie), czy tez to problem "globalny"?
Nie każdy jest mile widziany w moim domu. Gdybym wszystkich traktował jednakowo, nikogo nie wyróżniłbym!
Na górę
Zurwen
Posty: 756
Rejestracja: 13 lut 2009 09:37

Re: Zmud pomoc

Post autor: Zurwen »

Na szybko komenda #send dziala chyba
"napisz list;Nazwa_Adresata;Tytul_Listu;Tekst_listu;#send;Zwyczajowy_podpis;**"

Mnie strona zuggsoftu też nie działa.
Do kontaktów z czarodziejami służy komenda ‚zglos’ (błąd/pomysl/mg).
Na górę
Awatar użytkownika
Herenvarno
Posty: 809
Rejestracja: 09 mar 2010 11:22

Re: Zmud pomoc

Post autor: Herenvarno »

Niestety, "gole" #send nie chce sie wyslac..
Nie każdy jest mile widziany w moim domu. Gdybym wszystkich traktował jednakowo, nikogo nie wyróżniłbym!
Na górę
ODPOWIEDZ

Wróć do „Forum Techniczne”